@prefix this: <https://w3id.org/np/RA55g61pXEhYE3w1HGnAbLoPv781_ShXcXkiKneFnJQdU> .
@prefix sub: <https://w3id.org/np/RA55g61pXEhYE3w1HGnAbLoPv781_ShXcXkiKneFnJQdU/> .
@prefix np: <http://www.nanopub.org/nschema#> .
@prefix grlc: <https://w3id.org/kpxl/grlc/> .
@prefix dct: <http://purl.org/dc/terms/> .
@prefix nt: <https://w3id.org/np/o/ntemplate/> .
@prefix npx: <http://purl.org/nanopub/x/> .
@prefix xsd: <http://www.w3.org/2001/XMLSchema#> .
@prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#> .
@prefix orcid: <https://orcid.org/> .
@prefix prov: <http://www.w3.org/ns/prov#> .
@prefix foaf: <http://xmlns.com/foaf/0.1/> .

sub:Head {
  this: a np:Nanopublication;
    np:hasAssertion sub:assertion;
    np:hasProvenance sub:provenance;
    np:hasPublicationInfo sub:pubinfo .
}

sub:assertion {
  sub:get-openaire-project-outputs a grlc:grlc-query;
    dct:description "Returns the contributed links stating that a research product is an output of a funded project, with labels and contributor, excluding retracted or superseded nanopublications (example nanopublications are included, marked in the flags column). The status column links the latest valid approval or disapproval by a member of the given space.";
    dct:license <http://www.apache.org/licenses/LICENSE-2.0>;
    rdfs:label "Get OpenAIRE project outputs";
    grlc:endpoint <https://w3id.org/np/l/nanopub-query-1.1/repo/type/f9ff9a42593a73090517a1bd887520b4247cc6aea07bf945d829df84db53e8e2>;
    grlc:sparql """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix dct: <http://purl.org/dc/terms/>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix owl: <http://www.w3.org/2002/07/owl#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix cito: <http://purl.org/spar/cito/>
prefix frbr: <http://purl.org/vocab/frbr/core#>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix frapo: <http://purl.org/cerif/frapo/>
prefix prov: <http://www.w3.org/ns/prov#>
prefix gen: <https://w3id.org/kpxl/gen/terms/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
select ?product ?product_label ?project ?project_label ?flags ?creator ?creator_label ?date ?action_target ?np ?np_label ?status ?status_label where {
  {
    select ?product ?product_label ?project ?project_label
      (if(?isExample, \"example\", \"\") as ?flags)
      ?creator ?creator_label ?date (?np as ?action_target) ?np (\"^\" as ?np_label)
      (max(if(contains(?memberPubkeys, ?vKey), ?vTag, \"\")) as ?latestTag)
    where {
      values ?_space_multi_iri {}
      service <https://w3id.org/np/l/nanopub-query-1.1/repo/spaces> {
        select (group_concat(?mpk; separator=\" \") as ?memberPubkeys) where {
          graph npa:graph { <http://purl.org/nanopub/admin/thisRepo> npa:hasCurrentSpaceState ?stateG . }
          values ?_space_multi_iri {}
          graph ?stateG {
            ?ri a gen:RoleInstantiation ; npa:forSpace ?_space_multi_iri ; npa:forAgent ?agent ; npa:hasRoleType ?roleType .
            filter(?roleType in (gen:AdminRole, gen:MaintainerRole, gen:MemberRole))
            ?acct a npa:AccountState ; npa:agent ?agent ; npa:pubkey ?mpk .
          }
        }
      }
      graph npa:graph {
        ?np npa:hasValidSignatureForPublicKeyHash ?pk .
        filter not exists { ?inp npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pk . }
        filter not exists { ?sup npx:supersedes ?np . }
        ?np dct:created ?date .
        ?np np:hasAssertion ?a .
        ?np np:hasPublicationInfo ?pi .
      }
      graph ?a { ?product frapo:isOutputOf ?project . }
      filter( ( strstarts(str(?product), \"https://doi.org/\") || strstarts(str(?product), \"https://api.openaire.eu/\") ) && ( strstarts(str(?project), \"https://doi.org/\") || strstarts(str(?project), \"https://api.openaire.eu/\") ) )
      optional { graph ?pi { ?product nt:hasLabelFromApi ?product_label . } }
      optional { graph ?pi { ?project nt:hasLabelFromApi ?project_label . } }
      optional { graph npa:graph { ?np dct:creator ?creator . } }
      optional { graph ?pi { ?creator foaf:name ?creator_label . } }
      bind(exists { graph npa:graph { ?np npx:hasNanopubType npx:ExampleNanopub . } } as ?isExample)
      optional {
        { select (?vTarget as ?np) ?vKey ?vTag where {
            {
              service <https://w3id.org/np/l/nanopub-query-1.1/repo/type/4a9a4dc2fa939033dd444d4f630fec3450eee305d98dd9945f110b2a6bb51317> {
                graph npa:graph {
                  ?vnp npa:hasValidSignatureForPublicKeyHash ?vKey .
                  filter not exists { ?vinp npx:invalidates ?vnp ; npa:hasValidSignatureForPublicKeyHash ?vKey . }
                  filter not exists { ?vsup npx:supersedes ?vnp . }
                  ?vnp dct:created ?vDate .
                  ?vnp np:hasAssertion ?va .
                  ?vnp np:hasPublicationInfo ?vpi .
                }
                graph ?va { ?vagent npx:approvesOf ?vTarget . }
                optional { graph ?vpi { ?vagent foaf:name ?vName . } }
                bind(concat(str(?vDate), \">approved|\", coalesce(?vName, str(?vagent)), \"|\", str(?vnp)) as ?vTag)
              }
            } union {
              service <https://w3id.org/np/l/nanopub-query-1.1/repo/type/39692876d0a7881c82e9a2cb6dc8859fb16fa69fb41cea2ace2f8fa70bc52aed> {
                graph npa:graph {
                  ?vnp npa:hasValidSignatureForPublicKeyHash ?vKey .
                  filter not exists { ?vinp npx:invalidates ?vnp ; npa:hasValidSignatureForPublicKeyHash ?vKey . }
                  filter not exists { ?vsup npx:supersedes ?vnp . }
                  ?vnp dct:created ?vDate .
                  ?vnp np:hasAssertion ?va .
                  ?vnp np:hasPublicationInfo ?vpi .
                }
                graph ?va { ?vagent npx:disapprovesOf ?vTarget . }
                optional { graph ?vpi { ?vagent foaf:name ?vName . } }
                bind(concat(str(?vDate), \">disapproved|\", coalesce(?vName, str(?vagent)), \"|\", str(?vnp)) as ?vTag)
              }
            }
          }
        }
      }
    }
    group by ?product ?product_label ?project ?project_label ?creator ?creator_label ?date ?np ?isExample ?memberPubkeys
  }
  bind(coalesce(?latestTag, \"\") as ?lt)
  bind(strbefore(strafter(?lt, \">\"), \"|\") as ?verdict)
  bind(strafter(?lt, \"|\") as ?vrest)
  bind(strbefore(?vrest, \"|\") as ?vname)
  bind(iri(strafter(?vrest, \"|\")) as ?status)
  bind(xsd:dateTime(strbefore(?lt, \">\")) as ?vdt)
  bind((year(now())*525600 + month(now())*43800 + day(now())*1440 + hours(now())*60 + minutes(now())) - (year(?vdt)*525600 + month(?vdt)*43800 + day(?vdt)*1440 + hours(?vdt)*60 + minutes(?vdt)) as ?minsAgo)
  bind(coalesce(if(?minsAgo < 1, \"just now\", if(?minsAgo < 60, concat(str(?minsAgo), if(?minsAgo = 1, \" minute ago\", \" minutes ago\")), if(?minsAgo < 1440, concat(str(xsd:integer(floor(?minsAgo / 60))), if(xsd:integer(floor(?minsAgo / 60)) = 1, \" hour ago\", \" hours ago\")), concat(str(xsd:integer(floor(?minsAgo / 1440))), if(xsd:integer(floor(?minsAgo / 1440)) = 1, \" day ago\", \" days ago\"))))), \"\") as ?ago)
  bind(coalesce(if(?lt != \"\", concat(?verdict, \" by \", ?vname, \" \", ?ago), \"\"), \"\") as ?status_label)
}
order by desc(?date)""" .
}

sub:provenance {
  sub:assertion prov:wasAttributedTo orcid:0000-0002-1267-0234 .
}

sub:pubinfo {
  orcid:0000-0002-1267-0234 foaf:name "Tobias Kuhn" .
  
  this: dct:created "2026-07-29T17:53:26Z"^^xsd:dateTime;
    dct:creator orcid:0000-0002-1267-0234;
    dct:license <https://creativecommons.org/licenses/by/4.0/>;
    npx:embeds sub:get-openaire-project-outputs;
    npx:supersedes <https://w3id.org/np/RAus0UnvMFwX3cMXME88G7EcrXOh7R4r3llWq977RDGTM>;
    rdfs:label "Get OpenAIRE project outputs";
    nt:wasCreatedFromProvenanceTemplate <http://purl.org/np/RAcm8OurwUk15WOgBM9wySo-T3a5h6as4K8YR5MBrrxUc>;
    nt:wasCreatedFromPubinfoTemplate <https://w3id.org/np/RACJ58Gvyn91LqCKIO9zu1eijDQIeEff28iyDrJgjSJF8>,
      <https://w3id.org/np/RARW4MsFkHuwjycNElvEVtuMjpf4yWDL10-0C5l2MqqRQ>, <https://w3id.org/np/RAoTD7udB2KtUuOuAe74tJi1t3VzK0DyWS7rYVAq1GRvw>,
      <https://w3id.org/np/RAukAcWHRDlkqxk7H2XNSegc1WnHI569INvNr-xdptDGI>;
    nt:wasCreatedFromTemplate <https://w3id.org/np/RAEFAt-QcFK0ZhqfvlsmS10BnzGJA0xwOICZXkO-ai87k> .
  
  sub:sig npx:hasAlgorithm "RSA";
    npx:hasPublicKey "MIGfMA0GCSqGSIb3DQEBAQUAA4GNADCBiQKBgQCwUtewGCpT5vIfXYE1bmf/Uqu1ojqnWdYxv+ySO80ul8Gu7m8KoyPAwuvaPj0lvPtHrg000qMmkxzKhYknEjq8v7EerxZNYp5B3/3+5ZpuWOYAs78UnQVjbHSmDdmryr4D4VvvNIiUmd0yxci47dTFUj4DvfHnGd6hVe5+goqdcwIDAQAB";
    npx:hasSignature "IGJF2Ci4U4BnY7Dgf9oYWOAokQqtdmelhfYCV+7Bijnu2wUwufsAhB6RO6wnShgc5aYaAPjQnpO5P6620Ud9DTxUPfFEzu11mBkAt0BVehsrLSEDsGQ8Fa2314e0qE6CeziOtpGQ7Pu+XbEOeSTrutDsXMbqiBWt2z65LaLW4MU=";
    npx:hasSignatureTarget this:;
    npx:signedBy orcid:0000-0002-1267-0234 .
}